Very Easy Question

It's been a while so excuse the easy question here. I want to set location of flow items on a pallet. So I used the setloc (item,xx,xx,xx) command and I know it doesn't work because the item is the pallet. How do I reference the items packed on the rack in order to use the setloc command in this case.

Thanks...

rank(item, N) will return a reference to the Nth flowitem within the specified item.

I'm trying to use the tote flow item as a pallet. So I go to the flow item bin and create a new pallet and attempt to change the 3d shape by pointing to the Tote. This isn't working. I want to then pack the tote onto a cart. So I would be stacking a “pallet” on top of “pallet.” I plan to run it through a combiner a second time with a cart as the “pallet.” I think this would work?


Any help would be greatly appreciated..

I would use the "Box" instead of the "Pallet" for what you are trying to do. There would not be any problems with positioning other Items on it ;-)

Here is some code that you can use in a combiner's On Entry trigger. It is basically the same code that the pallet uses to stack flowitems, but it will stack flowitems into any other flowitem that comes through port 1 of a combiner.

The biggest difference I made to the code was add a buffer or spacing zone for inside the container. This can help prevent the flowitems from overlapping with the container's edges. For example, if you click on an object, you'll see the yellow box appear that indicates the dimensions of the object. In the code, when you put a number for the X buffer, this box effectively shrinks by the amount of the buffer in the X direction. And actually, it shrinks by twice the amount of the X buffer because the code assumes you want a buffer from both edges of the yellow box in the X direction. This is also true for the Y buffer, but the Z value only sets a buffer from the bottom of the container. If you don't care at all about the edges overlapping, just leave the values as 0 and the flowitems will stick stack correctly.

You can copy all the code from this post and paste it over the default header code on the On Entry trigger of the combiner to get it to work.

treenode item = parnode(1);
treenode current = ownerobject(c);
int port = parval(2);
{ //************* PickOption Start *************\\
/**Combine flowitems into any container.  Choose a buffer for the X, Y, and Z directions so the flowitems will not overlap with the container's edges.*/
/***popup:CombineItems*/
// If the flowitem is coming through port 1, then the flowitem is the container.
if(port == 1){
	// Used to make sure the flowitems look right in the container.
	switch_variable(item,"nochildscale",1);
}
// All other ports are used for the flowitems going into the container.
else{
	treenode container = first(current);
	treenode lastItem;
	/* The buffers are used to effectively shrink the area that the
	flowitems can be placed inside the container.  This is to help
	prevent any graphics overlap with the flowitems and the container edges.*/
	/** \nx: */
	double xBuffer = /***tag:nx*//**/0/**/;
	/** \ny: */
	double yBuffer = -/***tag:ny*//**/0/**/;
	/** \nz: */
	double zBuffer = /***tag:nz*//**/0/**/;
	/* Same idea as the buffers, except this will make sure all four
	sides of the container are included.  Otherwise, only one wall in
	the X or Y direction would container the buffer.*/
	double containerSX = xsize(container) - 2*xBuffer;
	double containerSY = ysize(container) + 2*yBuffer;
	if(content(container) != 0)	{
		lastItem = last(container);
	}
	// If this is the first item.
	if(content(container) == 0)	{
		setloc(item,xBuffer,yBuffer,zBuffer);
	}
	// Else if there is room between the right side of the last flowitem and the "east" wall of the container.
	else if(containerSX - (xloc(lastItem) + xsize(lastItem)) >= xsize(item)){
		setloc(item, xloc(lastItem) + xsize(lastItem), yloc(lastItem), zloc(lastItem));
	}
	// Else if there is room between the bottom of the last flowitem and the "south" wall of the container.
	else if(containerSY - (ysize(lastItem) - yloc(lastItem)) >= ysize(item)){
		setloc(item, xBuffer, -1 * (ysize(lastItem) - yloc(lastItem)), zloc(lastItem));
	}
	// Otherwise, put the flowitem on top of the layer that contains the last item.
	else{
		setloc(item, xBuffer, yBuffer, zloc(lastItem) + zsize(lastItem));
	}
}
} //******* PickOption End *******\\